UNIVARIATEプロシジャ

データ分布のモデル化

前の例のようなデータ分布の要約に加えて、UNIVARIATEプロシジャを使用して、データの無作為抽出に基づき、分布を統計的にモデル化することができます。次のステートメントは、30個の航空機部品サンプルの位置偏差の測定値を含む、Aircraftという名前のデータセットを作成します。

data Aircraft;
   input Deviation @@;
   label Deviation = 'Position Deviation';
   datalines;
-.00653 0.00141 -.00702 -.00734 -.00649 -.00601
-.00631 -.00148 -.00731 -.00764 -.00275 -.00497
-.00741 -.00673 -.00573 -.00629 -.00671 -.00246
-.00222 -.00807 -.00621 -.00785 -.00544 -.00511
-.00138 -.00609 0.00038 -.00758 -.00731 -.00455
;

分析では、測定値の分布が正規分布であるかどうかがまず問題になります。次のステートメントは、図4.5および図4.6に示す、積率のテーブル、正規性の検定および正規確率プロットを要求します。

title 'Position Deviation Analysis';
ods graphics on;
ods select Moments TestsForNormality ProbPlot;
proc univariate data=Aircraft normaltest;
   var Deviation;
   probplot Deviation / normal(mu=est sigma=est)
                        square
                        odstitle = title;
   label Deviation = 'Position Deviation';
   inset  mean std / format=6.4;
run;

UNIVARIATEプロシジャは、変数Deviationに関連付けられたラベルを確率プロットの垂直軸ラベルとして使用します。INSETステートメントは、標本平均および標本標準偏差を確率プロットに表示します。

図4.5: 積率および正規性の検定

Position Deviation Analysis

The UNIVARIATE Procedure

Variable: Deviation (Position Deviation)

Moments
N	30	Sum Weights	30
MEAN	-0.0053067	Sum Observations	-0.1592
Std Deviation	0.00254362	Variance	6.47002E-6
Skewness	1.2562507	Kurtosis	0.69790426
Uncorrected SS	0.00103245	Corrected SS	0.00018763
Coeff Variation	-47.932613	Std Error Mean	0.0004644

Tests for Normality
Test	Statistic		p Value
Shapiro-Wilk	W	0.845364	Pr < W	0.0005
Kolmogorov-Smirnov	D	0.208921	Pr > D	<0.0100
Cramer-von Mises	W-Sq	0.329274	Pr > W-Sq	<0.0050
Anderson-Darling	A-Sq	1.784881	Pr > A-Sq	<0.0050

図4.5の4つすべての適合度検定は、測定値が正規分布であるという仮定を棄却します。

図4.6は測定の正規確率プロットを示します。対角方向の参照線に沿った線形の点のパターンは、測定が正規分布であることを示します。一方、曲線の点のパターンは、正規分布よりも対数正規などの片寄った分布が適していることを示します。

例4.26では、Deviationの対数正規分布が当てはめられます。

この例のサンプルプログラムunivar2.sasは、Base SASソフトウェアのSASサンプルライブラリに含まれています。

図4.6: 正規確率プロット