UNIVARIATEプロシジャ

例4.34 Weibull分位点プロットの比較

この例では、48個の集積回路の故障時間(月数)に対する3パラメータおよび2パラメータWeibull Q-Qプロットの使用を比較しています。この時間はWeibull分布に従うと仮定します。次のステートメントは、故障時間を変数Timeの値としてデータセットFailuresに保存します。 

data Failures;
   input Time @@;
   label Time = 'Time in Months';
   datalines;
29.42 32.14 30.58 27.50 26.08 29.06 25.10 31.34
29.14 33.96 30.64 27.32 29.86 26.28 29.68 33.76
29.32 30.82 27.26 27.92 30.92 24.64 32.90 35.46
30.28 28.36 25.86 31.36 25.26 36.32 28.58 28.88
26.72 27.42 29.02 27.54 31.60 33.46 26.78 27.82
29.18 27.94 27.66 26.42 31.00 26.64 31.44 32.52
;

この分布のパラメータに関する前提がない場合、WEIBULLオプションを使用して3パラメータWeibullプロットを要求できます。前の例にあるように、形状パラメータcは、さまざまなc値に対するプロットを要求し、点のパターンが線形になるcの値を選択することによって、視覚的に推定できます。または、次のステートメントに示すように、cの最尤推定値を要求することもできます。 

title 'Three-Parameter Weibull Q-Q Plot for Failure Times';
ods graphics on;
proc univariate data=Failures noprint;
   qqplot Time / weibull(c=est theta=est sigma=est)
                 square
                 href     = 0.5 1 1.5 2
                 vref     = 25 27.5 30 32.5 35
                 odstitle = title;
run;

注: WEIBULLオプションを使用する場合、C=オプションでWeibull形状パラメータcのリストを指定するか、C=ESTを指定する必要があります。

出力4.34.1には、推定値$\hat{c}=1.99$に対するプロットが表示されています。参照線は、しきい値パラメータと尺度パラメータがそれぞれ$\hat{\theta }=24.19$および$\hat{\sigma }_0=5.83$の推定値に対応しています。

出力4.34.1: 3パラメータWeibull Q-Qプロット

3パラメータWeibull Q-Qプロット


ここで、回路の寿命が24か月以上であることがわかっているとします。次のステートメントは、既知のしきい値$\theta _0=24$を使用して、出力4.31.4に示すような2パラメータWeibull Q-Qプロットを作成します。 

title 'Two-Parameter Weibull Q-Q Plot for Failure Times';
proc univariate data=Failures noprint;
   qqplot Time / weibull(theta=24 c=est sigma=est)
                 square
                 vref     = 25 to 35 by 2.5
                 href     = 0.5 to 2.0 by 0.5
                 odstitle = title;
run;

参照線は、最尤推定値$\hat{c}=2.08$および$\hat{\sigma }=6.05$に基づいています。

出力4.34.2: 2パラメータWeibull Q-Qプロット($\theta _0=24$)

2パラメータWeibull Q-Qプロット(θ0=24)


この例のサンプルプログラムuniex19.sasは、Base SASソフトウェアのSASサンプルライブラリに含まれています。