UNIVARIATEプロシジャ

例4.18 ヒストグラムのビン幅の指定

この例は例4.14の続きで、ヒストグラムのビン幅を指定するさまざまな方法を示しています。この例は、ビンのパーセンテージをOUTHISTOGRAM=データセットに保存する方法も示しています。

例4.14のメーカーはENDPOINTS=オプションでビンの端点を変更し、ヒストグラムを拡張しようとしています。次のステートメントは、ビンの終点が3.425および3.6で幅が0.025のヒストグラムを作成します。

title 'Enhancing a Histogram';
ods select Histogram HistogramBins;
proc univariate data=Trans;
   histogram Thick / midpercents
                     endpoints = 3.425 to 3.6 by .025
                     odstitle  = title;
run;

ODS SELECTステートメントは出力を"HistogramBins"テーブルと"MyHist"ヒストグラムに制限します。ODSテーブル名のセクションを参照してください。ENDPOINTS=オプションはヒストグラムビンの端点を指定します。デフォルトでは、ENDPOINTS=オプションが指定されていない場合、ビン幅を自動的に指定するアルゴリズムによって、ビンの中間点の値が計算されます。MIDPERCENTSオプションは、各ヒストグラムビンの中間点と各ビンに含まれるオブザベーションのパーセントのテーブルを要求します。テーブルは出力4.18.1に表示され、ヒストグラムは出力4.18.2に表示されています。NAME=オプションは、ODS SELECTステートメントで使用できるヒストグラムの名前を指定します。

出力4.18.1: MIDPERCENTSオプションで要求したビンのパーセンテージのテーブル

Enhancing a Histogram

The UNIVARIATE Procedure

Histogram Bins for Thick
Bin Minimum Point	Observed Percent
3.425	8.000
3.450	21.000
3.475	25.000
3.500	29.000
3.525	11.000
3.550	5.000
3.575	1.000

出力4.18.2: ENDPOINTS=オプションによるヒストグラム

MIDPOINTS=オプションは、ヒストグラムビンを指定する際のENDPOINTS=オプションの代替として使用できます。次のステートメントは出力4.18.3に示したヒストグラムを作成します。このヒストグラムは出力4.18.2のものと似ています。

title 'Enhancing a Histogram';
proc univariate data=Trans noprint;
   histogram Thick / midpoints    = 3.4375 to 3.5875 by .025
                     rtinclude
                     outhistogram = OutMdpts
                     odstitle     = title;
run;

出力4.18.3は出力4.18.2と2つの点で異なります。

MIDPOINTS=オプションは、端点を指定する代わりにビンの中間点を指定することにより、ヒストグラムのビンを指定します。端点ではなく中間点がヒストグラムに表示されます。
RTINCLUDEオプションは、各ビンの左の端点をヒストグラム間隔に含めるデフォルト設定の代わりに、各ビンの右の端点をヒストグラム間隔に含めるよう要求します。このため、出力4.18.2のヒストグラムから少し変化しています。6つのオブザベーションの厚さは間隔の端点に等しくなっています。たとえば、厚さが3.45mmのオブザベーションが1つあります。出力4.18.3では、このオブザベーションは3.425から3.45までのビンに含まれています。

出力4.18.3: MIDPOINTS=およびRTINCLUDEオプションによるヒストグラム

OUTHISTOGRAM=オプションは、出力4.18.4に表示されているOutMdptsという名前の出力データセットを作成します。このデータセットはヒストグラムのビンに関する情報を示します。詳細は、OUTHISTOGRAM=出力データセットのセクションを参照してください。

出力4.18.4: OUTHISTOGRAM=データセットOutMdpts

Enhancing a Histogram

Obs	_VAR_	_MIDPT_	_OBSPCT_	_COUNT_
1	Thick	3.4375	9	9
2	Thick	3.4625	21	21
3	Thick	3.4875	26	26
4	Thick	3.5125	28	28
5	Thick	3.5375	11	11
6	Thick	3.5625	5	5

この例のサンプルプログラムuniex08.sasは、Base SASソフトウェアのSASサンプルライブラリに含まれています。