UNIVARIATEプロシジャ

例4.22 対数正規曲線、Weibull曲線、ガンマ曲線の当てはめ

適切なデータ分布モデルを決定するには、いくつかの分布族の曲線を検討する必要があります。この例で示すように、HISTOGRAMステートメントを使用して複数の分布を当てはめ、それらの密度曲線を1つのヒストグラムに表示することができます。

溶接工程の生産品から無作為に50個の溶接済み組み立て品を選択し、各組立品の2つの金属板の間の隙間(cm)を測定します。次のステートメントはPlatesという名前のデータセットに測定値(Gap)を保存します。

data Plates;
   label Gap = 'Plate Gap in cm';
   input Gap @@;
   datalines;
0.746  0.357  0.376  0.327  0.485 1.741  0.241  0.777  0.768  0.409
0.252  0.512  0.534  1.656  0.742 0.378  0.714  1.121  0.597  0.231
0.541  0.805  0.682  0.418  0.506 0.501  0.247  0.922  0.880  0.344
0.519  1.302  0.275  0.601  0.388 0.450  0.845  0.319  0.486  0.529
1.547  0.690  0.676  0.314  0.736 0.643  0.483  0.352  0.636  1.080
;

次のステートメントは3つの分布(対数正規、Weibullおよびガンマ)を当てはめ、それらの密度曲線を1つのヒストグラムに表示します。

title 'Distribution of Plate Gaps';
ods graphics off;
ods select ParameterEstimates GoodnessOfFit FitQuantiles MyHist;
proc univariate data=Plates;
   var Gap;
   histogram / midpoints=0.2 to 1.8 by 0.2
               lognormal
               weibull
               gamma
               vaxis   = axis1
               name    = 'MyHist';
   inset n mean(5.3) std='Std Dev'(5.3) skewness(5.3)
          / pos = ne  header = 'Summary Statistics';
   axis1 label=(a=90 r=0);
run;

ODS SELECTステートメントは出力を"ParameterEstimates"、"GoodnessOfFit"および"FitQuantiles"の各テーブルに制限します。ODSテーブル名のセクションを参照してください。LOGNORMAL、WEIBULLおよびGAMMA 1次オプションは、当てはめた曲線を出力4.22.1のヒストグラムに重ねて表示するよう要求します。各曲線でしきい値パラメータはであることが前提になっています。しきい値が0ではない場合は、THETA= 2次オプションでを指定できます。

LOGNORMAL、WEIBULLおよびGAMMAオプションは、出力4.22.2～出力4.22.4に示されている当てはめた分布の要約も作成します。

出力4.22.2は、対数正規分布に対する3つのEDF適合度検定(Anderson-Darling、Cramér-von MisesおよびKolmogorov-Smirnov検定)を示しています。有意水準で、2パラメータ対数正規分布(尺度パラメータおよび形状パラメータ)が金属板の隙間の分布モデルに適しているという結論が、すべての検定で支持されます。

出力4.22.1 ヒストグラムと当てはめた曲線の重ね合わせ表示

出力4.22.3は、Weibull分布に対する2つのEDF適合度検定(Anderson-DarlingおよびCramér-von Mises検定)を示しています。EDF検定の値はすべて0.10より小さく、このデータがWeibullモデルを支持しないことを示しています。

この分析に基づき、当てはめた対数正規分布と当てはめたガンマ分布の2つのモデルが金属板の隙間の分布に適しています。

この例のサンプルプログラムuniex13.sasは、Base SASソフトウェアのSASサンプルライブラリに含まれています。