UNIVARIATEプロシジャ

例4.7 OUT=出力データセットへの要約統計量の保存

この例は、要約統計量を出力データセットに保存する方法を示しています。次のステートメントはBeltsという名前のデータセットを作成します。このデータセットには、50個の自動車用シートベルトのサンプルの破壊強度(Strength)と幅(Width)が含まれます。

data Belts;
   label Strength = 'Breaking Strength (lb/in)'
         Width    = 'Width in Inches';
   input Strength Width @@;
   datalines;
1243.51  3.036  1221.95  2.995  1131.67  2.983  1129.70  3.019
1198.08  3.106  1273.31  2.947  1250.24  3.018  1225.47  2.980
1126.78  2.965  1174.62  3.033  1250.79  2.941  1216.75  3.037
1285.30  2.893  1214.14  3.035  1270.24  2.957  1249.55  2.958
1166.02  3.067  1278.85  3.037  1280.74  2.984  1201.96  3.002
1101.73  2.961  1165.79  3.075  1186.19  3.058  1124.46  2.929
1213.62  2.984  1213.93  3.029  1289.59  2.956  1208.27  3.029
1247.48  3.027  1284.34  3.073  1209.09  3.004  1146.78  3.061
1224.03  2.915  1200.43  2.974  1183.42  3.033  1195.66  2.995
1258.31  2.958  1136.05  3.022  1177.44  3.090  1246.13  3.022
1183.67  3.045  1206.50  3.024  1195.69  3.005  1223.49  2.971
1147.47  2.944  1171.76  3.005  1207.28  3.065  1131.33  2.984
1215.92  3.003  1202.17  3.058
;

次のステートメントは要約統計量を含む2つの出力データセットを作成します。

proc univariate data=Belts noprint;
   var Strength Width;
   output out=Means         mean=StrengthMean WidthMean;
   output out=StrengthStats mean=StrengthMean std=StrengthSD 
                            min=StrengthMin   max=StrengthMax;
run;

OUTPUTステートメントを指定する場合、VARステートメントも指定する必要があります。1つのプロシジャステートメントで複数のOUTPUTステートメントを使用できます。OUTPUTステートメントごとに、OUT=オプションで指定した名前の新しいデータセットが作成されます。この例では、2つのデータセットMeansおよびStrengthStatsが作成されます。Meansのリストは出力4.7.1、StrengthStatsのリストは出力4.7.2を参照してください。

出力4.7.1 出力データセットMeansのリスト

Analysis of Speeding Data

Obs	StrengthMean	WidthMean
1	1205.75	3.00584

出力4.7.2 出力データセットStrengthStatsのリスト

Analysis of Speeding Data

Obs	StrengthMean	StrengthSD	StrengthMax	StrengthMin
1	1205.75	48.3290	1289.59	1101.73

OUT=オプションの後にキーワード=名前を指定することにより、要約統計量が出力データセットに保存されます。前のステートメントで、最初のOUTPUTステートメントではキーワードMEANの後に、名前StrengthMeanおよびWidthMeanが指定されています。2番目のOUTPUTステートメントではキーワードMEAN、STD、MAX、MINが指定され、それぞれの名前としてStrengthMean、StrengthSD、StrengthMax、StrengthMinが指定されています。

キーワードは出力データセットに保存される統計量を指定し、名前は新しい変数の名前を決定します。キーワードの後のリストの最初の名前には、VARステートメントのリストの最初の変数に対するその統計量が含まれます。2番目の名前には、VARステートメントの2番目の変数に対するその統計量が含まれます。

データセットMeansでは、Strengthの平均がStrengthMeanという名前の変数に格納され、Widthの平均がWidthMeanという名前の変数に格納されています。データセットStrengthStatsでは、Strengthの平均、標準偏差、最大値、最小値が、それぞれ、変数StrengthMean、StrengthSD、StrengthMax、StrengthMinに格納されています。

OUT=出力データセットの詳細は、OUTPUTステートメントのOUT=出力データセットのセクションを参照してください。

この例のサンプルプログラムuniex06.sasは、Base SASソフトウェアのSASサンプルライブラリに含まれています。