CORRプロシジャ

次のステートメントは、データセットFish1(例2.6で作成されたもの)内にある変数を使用して相関分析を実施し、散布図を作成します。

ods graphics on;
title 'Fish Measurement Data';
proc corr data=fish1 nomiss plots=matrix(histogram);
   var Height Width Length3 Weight3;
run;
ods graphics off;

出力2.8.1の表"Simple Statistics"には、分析変数の単変量統計量が示されています。

出力 2.8.2の表"Pearson Correlation Coefficients"には、分析変数ペアのPearsonの相関統計量が示されています。

これらの変数の間には高い相関があります。たとえば、変数HeightとWidthの間の相関は0.92632です。

PLOTS=MATRIX(HISTOGRAM)オプションを指定すると、出力2.8.3に示すようなVAR変数を使用した散布図行列が作成されます。

出力2.8.3: 散布図行列

このグラフ表示を要求するには、ODS Graphicsを有効にし、PLOTS=オプションを指定します。ODS Graphicsの詳細は、SAS/STAT 13.2 User's GuideのChapter 21: Statistical Graphics Using ODSを参照してください。

HeightとWidth間の相関を調べる場合、次のステートメントにより、出力2.8.4に示すような、2変数の予測楕円付きの散布図を作成します。

ods graphics on;
proc corr data=fish1 nomiss
          plots=scatter(nvar=2 alpha=.20 .30);
   var Height Width Length3 Weight3;
run;
ods graphics off;

PLOTS=SCATTER(NVAR=2)オプションを指定すると、VARリスト内の最初の2つの変数を使った散布図が作成されます。ALPHA=.20 .30サブオプションは、それぞれおよびの予測楕円を要求します。

出力2.8.4: 予測楕円付きの散布図

予測楕円とは、2変量正規性を仮定して母集団内の新しいオブザベーションを予測するための領域です。またこれは、母集団の指定した割合を含む領域に近似します。表示される予測楕円は、平均を中心としています。詳細は、信頼楕円と予測楕円のセクションを参照してください。

次のステートメントも、出力2.8.5に示すような、変数HeightとWidthを使った散布図を作成します。

ods graphics on;
proc corr data=fish1
          plots=scatter(alpha=.20 .30);
   var Height Width;
run;
ods graphics off;

出力2.8.5: 予測楕円付きの散布図

出力2.8.5には点が含まれています。この点は、出力2.8.4からは除外されていました。これは、オブザベーションがWeight3で欠損値を含んでいたためです。出力2.8.5の予測楕円には、このオブザベーションの包含も反映されています。

次のステートメントは、出力2.8.6に示すような、平均の信頼楕円を作成します。

ods graphics on;
title 'Fish Measurement Data';
proc corr data=fish1 nomiss
          plots=scatter(ellipse=confidence nvar=2 alpha=.05 .01);
   var Height Width Length3 Weight3;
run;
ods graphics off;

PLOTS=オプションに続いてNVAR=2サブオプションを指定すると、VARステートメント内の最初の2つの変数に対して作成される散布図の数を制限できます。ELLIPSE=CONFIDENCEサブオプションは、平均の信頼楕円を要求します。ALPHA=.05 .01サブオプションは、それぞれおよびの信頼楕円を要求します。

出力2.8.6: 信頼楕円付きの散布図

この信頼楕円は、平均を中心としています。詳細は、信頼楕円と予測楕円のセクションを参照してください。