CORRプロシジャ

次のステートメントは、SAS/STAT 13.2 User's GuideのChapter 96: The STEPDISC Procedureで使用されているFishデータセットからデータセットFish1を作成します。重みの立方根(Weight3)は、魚のサイズの1次元測定値として計算されます。

*------------------- Fish Measurement Data ----------------------*
| The data set contains 35 fish from the species Bream caught in |
| Finland's lake Laengelmavesi with the following measurements:  |
| Weight   (in grams)                                            |
| Length3  (length from the nose to the end of its tail, in cm)  |
| HtPct    (max height, as percentage of Length3)                |
| WidthPct (max width,  as percentage of Length3)                |
*----------------------------------------------------------------*;
data Fish1 (drop=HtPct WidthPct);
   title 'Fish Measurement Data';
   input Weight Length3 HtPct WidthPct @@;
   Weight3= Weight**(1/3);
   Height=HtPct*Length3/100;
   Width=WidthPct*Length3/100;
   datalines;
242.0 30.0 38.4 13.4     290.0 31.2 40.0 13.8
340.0 31.1 39.8 15.1     363.0 33.5 38.0 13.3
430.0 34.0 36.6 15.1     450.0 34.7 39.2 14.2
500.0 34.5 41.1 15.3     390.0 35.0 36.2 13.4
450.0 35.1 39.9 13.8     500.0 36.2 39.3 13.7
475.0 36.2 39.4 14.1     500.0 36.2 39.7 13.3
500.0 36.4 37.8 12.0        .  37.3 37.3 13.6
600.0 37.2 40.2 13.9     600.0 37.2 41.5 15.0
700.0 38.3 38.8 13.8     700.0 38.5 38.8 13.5
610.0 38.6 40.5 13.3     650.0 38.7 37.4 14.8
575.0 39.5 38.3 14.1     685.0 39.2 40.8 13.7
620.0 39.7 39.1 13.3     680.0 40.6 38.1 15.1
700.0 40.5 40.1 13.8     725.0 40.9 40.0 14.8
720.0 40.6 40.3 15.0     714.0 41.5 39.8 14.1
850.0 41.6 40.6 14.9    1000.0 42.6 44.5 15.5
920.0 44.1 40.9 14.3     955.0 44.0 41.1 14.3
925.0 45.3 41.4 14.9     975.0 45.9 40.6 14.7
950.0 46.5 37.9 13.7
;

次のステートメントは、変数Weight3、Length3、Height、Widthの相関分析を要求し、Cronbachのアルファ係数を計算します。

ods graphics on;
title 'Fish Measurement Data';
proc corr data=fish1 nomiss alpha plots=matrix;
   var Weight3 Length3 Height Width;
run;
ods graphics off;

ALPHAオプションを指定すると、指定の分析変数を使ってCronbachのアルファ係数が計算されます。

出力2.6.1の表"Simple Statistics"には、各分析変数の単変量記述統計量が示されています。

出力 2.6.2の表"Pearson Correlation Coefficients"には、分析変数ペアのPearsonの相関統計量が示されています。

このデータセットには1種類の魚の情報のみが含まれているため、すべての変数には高い相関があります。ALPHAオプションを指定すると、CORRプロシジャは、出力2.6.3に示すようなCronbachのアルファ係数を計算します。Cronbachのアルファ係数は、未加工の変数と標準化変数の信頼係数の下限を表します。変数は共通のエンティティを測定するため、アルファ係数では正の相関が必要となります。

一部の変数では分散が大きく異なっているため、信頼性を推定するには標準化されたスコアを使用する必要があります。全体的に標準化されたCronbachのアルファ係数の値0.985145は、信頼係数の受け入れ可能な下限値を提供します。 これは、Nunnally and Bernstein (1994)による推奨値0.70よりもかなり大きい値となっています。

標準化されたアルファ係数は、各変数が標準化変数を使って尺度の信頼性をどのように反映するかについての情報を提供します。ある変数を構成概念から取り除くと標準化されたアルファ係数が減少する場合、その変数は尺度内の他の変数との間に強い相関を持ちます。一方、ある変数を構成概念から取り除くと標準化されたアルファ係数が増加する場合、その変数を尺度から取り除くことにより、構成概念の信頼性を高めることができます。出力2.6.4の表"Cronbach Coefficient Alpha with Deleted Variables"には、標準化されたアルファ係数の有意味な増加も減少も示されていません。詳細は、Cronbachのアルファ係数のセクションを参照してください。